پرفروش ترين
برترين
آخرين محصولات فروشگاه
فایل الکترونیکی آموزش اکسل پیشرفته ۲۰۱۰
آموزش ایجاد فایل چندکاربره با سطح دسترسی مشخص
یوزرفرم پیشرفته -Advanced  User Form
داشبورد (مقدماتی) – Dashboards(Elementary)
ابزارهای اعتبار سنجی و اخطار دهنده
بسته آموزشی userform
مدیریت و کنترل خطا در اکسل
توابع متنی
گرافیک در اکسل
جزوه آموزشی جداول و نمودارهای پاشنه ای
فایل آموزشی نحوه تهیه فرمت عددی دلخواه یا custom number format cell
آموزش ایجاد فایل چندکاربره با سطح دسترسی مشخص
نمایش نتایج: از شماره 1 تا 1 , از مجموع 1

موضوع: گزارش فیلتر در vba

  1. #1


    آخرین بازدید
    یک دقیقه پیش
    تاریخ عضویت
    September_2013
    محل سکونت
    بچه محل آقا امام رضا
    نوشته ها
    3,048
    امتیاز
    9051
    سپاس
    5,989
    سپاس شده
    7,387 در 2,451 پست

    Smiley گزارش فیلتر در vba


    سلام دوستان

    همونطور که میدونین در اکسل قابلیتی داریم به نام فیلتر کردن. گاهی ممکنه پیش بیاد بخواین یک محدوده رو فیلتر کنین. خب حالا فرض کنید بیست تا ستون رو فیلتر کردین و هر ستون رو بر اساس یک آیتم فیلتر کردین. فهمیدن اینکه بر چه اساسی فیلترها اعمال شدن در این حالت کار راحتی نیست. این کد کمک میکنه شما بفهمین هر ستون بر چه اساس فیلتر شده و همچنین بدونین محدوده فیلتر شدتون کجاست.

    این ظاهر این فایل هست اما اگر به کدها دقت کنید و یکم خلاق باشید میتونین متوجه بشید که چه کارهایی میشه با محدوده های فیلتر شده انجام داد مثلا اینکه بدونیم در یک ستون چند آیتم فیلتر شده و یا هر چیزی در مورد فیلتر ها

    کد:
    Sub ShowAutoFilterCriteria()
       Dim oAF As AutoFilter, oFlt As Filter
       Dim sField As String
       Dim sCrit1 As String, sCrit2 As String
       Dim sMsg As String, i As Integer
    
    
       'Check if the sheet is filtered at all
       If ActiveSheet.AutoFilterMode = False Then
          MsgBox "The sheet does not have an AutoFilter"
          Exit Sub
       End If
    
    
       'Get the sheet's AutoFilter object
       Set oAF = ActiveSheet.AutoFilter
    
    
       'Loop through the Filters of the AutoFilter
       For i = 1 To oAF.Filters.Count
    
    
          'Get the field name from the first row
          'of the AutoFilter range
          sField = oAF.Range.Cells(1, i).Value
    
    
          'Get the Filter object
          Set oFlt = oAF.Filters(i)
    
    
          'If the filter is on...
          If oFlt.On Then
    
    
             'Get the standard filter criteria
             sMsg = sMsg & vbCrLf & sField & oFlt.Criteria1
    
    
             'If it's a special filter, show it
             Select Case oFlt.Operator
                Case xlAnd
                   sMsg = sMsg & " And " & sField & oFlt.Criteria2
    
    
                Case xlOr
                   sMsg = sMsg & " Or " & sField & oFlt.Criteria2
    
    
                Case xlBottom10Items
                   sMsg = sMsg & " (bottom 10 items)"
    
    
                Case xlBottom10Percent
                   sMsg = sMsg & " (bottom 10%)"
    
    
                Case xlTop10Items
                   sMsg = sMsg & " (top 10 items)"
    
    
                Case xlTop10Percent
                   sMsg = sMsg & " (top 10%)"
    
    
             End Select
          End If
       Next
    
    
       If sMsg = "" Then
          'No filters are applied, so say so
          sMsg = "The range " & oAF.Range.Address & " is not filtered."
       Else
          'Filters are applied, so show them
          sMsg = "The range " & oAF.Range.Address & " is filtered by:" & sMsg
       End If
    
    
       'Display the message
       MsgBox sMsg
    End Sub

    فايل هاي پيوست شده فايل هاي پيوست شده

  2. سپاس ها (1)


  3.  


اطلاعات موضوع

کاربرانی که در حال مشاهده این موضوع هستند

در حال حاضر 1 کاربر در حال مشاهده این موضوع است. (0 کاربران و 1 مهمان ها)

بازدید کنندگان با جستجو های زیر این صفحه را پیدا کرده اند

انجمن اكسل ايران , اكسل , اكسس , سوال و جواب اكسل , سوال اكسس , انجمن اكسل ايران , توابع اكسل, آموزش اكسل, آموزش اكسس, VBA, ويژوال بيسيك

کلمات کلیدی این موضوع

مجوز های ارسال و ویرایش

  • شما نمیتوانید موضوع جدیدی ارسال کنید
  • شما امکان ارسال پاسخ را ندارید
  • شما نمیتوانید فایل پیوست کنید.
  • شما نمیتوانید پست های خود را ویرایش کنید
  •  
  • BB code ها فعال هستند
  • شکلک ها فعال هستند
  • کد [IMG] فعال است
  • کد [VIDEO] فعال است
  • کد HTML غیر فعال است