پرسش استفاده از نرم افزار اکسل فقط با یک پسورد خاص

[moghatarian]

با سلام به همه اساتید و دوستان عزیز

من میخام نرم افزار اکسل با یه پسورد خاص باز بشه و یا روی کل فایل های اکسل یک سیستم یک پسورد یکسان اعمال بشه و این پسورد

به طور خودکار روی هرفالی که ذخیره میشه اعمال بشه .

( در ضمن نمیتونم از هیچ نرم افزار قفل گذازی استفاده کنم )

ممنون از همه

[a.dal65]

دوست عزیز این قسمت سوالتون

من میخام نرم افزار اکسل با یه پسورد خاص باز بشه

اگه منظورتون فایل های اکسل نیست و برای باز کردن خود excel.exe میخواید ، چون قید کردید بدون نرم افزار هیچ راهی نداره !

ولی اگه روی فایل های اکسل بخواید بزارید (بدون نرم افزار) باید تک تک فایل هاتون باز کنید و روش رمز بزارید ،

https://forum.exceliran.com/showthread.php/337-%D9%86%D8%AD%D9%88%D9%87-protect-%D9%83%D8%B1%D8%AF%D9%86-%D9%8A%D9%83-%D9%81%D8%A7%D9%8A%D9%84-%D8%AF%D8%B1-%D8%A7%D9%83%D8%B3%D9%84-2007

که با این کار فایل شما رمز گذاری میشه و در هنگام باز شدن روی هر سیستمی رمز میخواد

[moghatarian]

با تشکر از پاسخ شما دوست عزیز

نحوه پسورد گذاشتن روی فایل هارو بلدم .

من میخام یکی از موارد زیر عملی بشه

1- یا نرم افزار اکسل با پسورد باز بشه . ( بدون نرم افزار واسط )

2- یا فایل های اکسل یه سیستم همه با یک پسورد یکسان محافظت بشه .

با تشکر

[حسام بحرانی]

با تشکر از پاسخ شما دوست عزیز
نحوه پسورد گذاشتن روی فایل هارو بلدم .
من میخام یکی از موارد زیر عملی بشه
1- یا نرم افزار اکسل با پسورد باز بشه . ( بدون نرم افزار واسط )
2- یا فایل های اکسل یه سیستم همه با یک پسورد یکسان محافظت بشه .
با تشکر

سلام دوست عزیز
میشه دلیل این کار رو بگید؟!

شاید اگر دلیلتون رو بگید برای اون بشه راهکار بهتری ارائه داد.

موفق باشید.

[a.dal65]

با ماکرو زیز شما میتونید رو فایل های اکسلی که روی سیستموتون هست به صورت یکجا رمز بزارید .
(دیگه نیازی نیست تک تک فایل هاتونو باز کنید و رمز بزارید)

فقط خط اول و دوم نیاز به ویرایش داره(پسورد و دایرکتوری که شما میخواید درون اون تمام فایل ها پسورد گذاری بشه)

بعد ماکرو ListAllFilesInDirectoryStructure رو اجرا کنید

Const cstPass As String = "pass"
Const cstRoot As String = "D:\1"
Dim aFiles() As String, iFile As Integer

Sub ListAllFilesInDirectoryStructure()
  iFile = 0
  ListFilesInDirectory cstRoot & "\"
  ProcessFiles
End Sub
 
Sub ListFilesInDirectory(Directory As String)
  Dim aDirs() As String, iDir As Integer, stFile As String
 
  ' use Dir function to find files and directories in Directory
  ' look for directories and build a separate array of them
  ' note that Dir returns files as well as directories when vbDirectory specified
  iDir = 0
  stFile = Directory & Dir(Directory & "*.*", vbDirectory)
  Do While stFile <> Directory
    If Right(stFile, 2) = "\." Or Right(stFile, 3) = "\.." Then
      ' do nothing - GetAttr doesn't like these directories
    ElseIf (GetAttr(stFile) And vbDirectory) = vbDirectory Then
      ' add to local array of directories
      iDir = iDir + 1
      ReDim Preserve aDirs(1 To iDir)
      aDirs(iDir) = stFile
    ElseIf InStr(LCase(stFile), ".xl") > 0 Then ' any excel file
      ' add to global array of files
      iFile = iFile + 1
      ReDim Preserve aFiles(1 To iFile)
      aFiles(iFile) = stFile
    End If
    stFile = Directory & Dir()
  Loop
   
  ' now, for any directories in aDirs call self recursively
  If iDir > 0 Then
    For iDir = 1 To UBound(aDirs)
      ListFilesInDirectory aDirs(iDir) & Application.PathSeparator
    Next iDir
  End If
End Sub

Sub ProcessFiles()
  Dim WB As Workbook
  For iFile = 1 To UBound(aFiles)
    Set WB = Workbooks.Open(aFiles(iFile))
    WB.ReadOnlyRecommended = False
    Application.DisplayAlerts = False  ' inhibit the overwrite? dialog
    WB.SaveAs aFiles(iFile), Password:=cstPass
    Application.DisplayAlerts = True
    WB.Close False
  Next
End Sub 

منبع :https://answers.microsoft.com/en-us/...599b31bf5?db=5