درج شماره صفحه

[Rdezh]

با سلام از دوستان
چطوری می*توان در یک سلول دلخواه شماره صفحه را درج نمود؟

[generalsamad]

با سلام
شما میتوانید از این Function استفاده کنید.

Public Function PageNumber( _
        Optional ByRef target As Excel.Range, _
        Optional ByVal nStart As Long = 1&) As Variant
        Dim pbHorizontal As HPageBreak
        Dim pbVertical As VPageBreak
        Dim nHorizontalPageBreaks As Long
        Dim nPageNumber As Long
        Dim nVerticalPageBreaks As Long
        Dim nRow As Long
        Dim nCol As Long
        
        On Error GoTo ErrHandler
        Application.Volatile
        If target Is Nothing Then _
            Set target = Application.Caller
        With target
            nRow = .Row
            nCol = .Column
            With .Parent
                If .PageSetup.Order = xlDownThenOver Then
                    nHorizontalPageBreaks = .HPageBreaks.Count + 1&
                    nVerticalPageBreaks = 1&
                Else
                    nHorizontalPageBreaks = 1&
                    nVerticalPageBreaks = .VPageBreaks.Count + 1&
                End If
                nPageNumber = nStart
                For Each pbHorizontal In .HPageBreaks
                    If pbHorizontal.Location.Row > nRow Then Exit For
                    nPageNumber = nPageNumber + nVerticalPageBreaks
                Next pbHorizontal
                For Each pbVertical In .VPageBreaks
                    If pbVertical.Location.Column > nCol Then Exit For
                    nPageNumber = nPageNumber + nHorizontalPageBreaks
                Next pbVertical
            End With
        End With
        PageNumber = nPageNumber
ResumeHere:
        Exit Function
ErrHandler:
       
        PageNumber = CVErr(xlErrRef)
        Resume ResumeHere
End Function 

سپس در سلول دلخواه کلیک کنید و این تابع رو وارد کنید

=PageNumber() 

اگه تابع رو بدون آرگومان وارد کنید شروع صفحه از 1 میباشد
ولی اگه خواستید شروع صفحه از شمره خاصی شروع بشه باید فرمول رو به صورت زیر وارد کنید

=PageNumber(;6)